/********************************************************************************************************
										Requete SAE Q24 
******************************************************************************************************/
%macro q24(region,an2,version,calcul,selection); 
	%global an1; 
	%let an1=%substr(&an2,3); 
	data Q24_TMP1_&an1.; 
		format region $20.; 
		set sae&an1.adm.Q24_&an2.; 
		if substr(FI,1,2) in ("01" "03" "07" "15" "26" "38" "42" "43" "63" "69" "73" "74") then region="AURA"; 
		if substr(FI,1,2) in ("21" "25"	"39" "58" "70" "71" "89" "90") then region="BFC"; 
		if substr(FI,1,2) in ("22" "29" "35" "56") then region="BRETAGNE"; 
		if substr(FI,1,2) in ("18" "28" "36" "37" "41" "45") then region="CVL"; 
		if substr(FI,1,2) in ("2A" "2B") then region="CORSE"; 
		if substr(FI,1,2) in ("08" "10" "51" "52" "54" "55" "57" "67" "68" "88") then region="GRANDEST"; 
		if substr(FI,1,2) in ("02" "59" "60" "62" "80") then region="HAUTDEFRANCE"; 
		if substr(FI,1,2) in ("75" "77" "78" "91" "92" "93" "94" "95") then region="ILEDEFRANCE"; 
		if substr(FI,1,2) in ("14" "27" "50" "61" "76") then region="NORMANDIE"; 
		if substr(FI,1,2) in ("16" "17" "19" "23" "24" "33" "40" "47" "64" "79" "86" "87") then region="NOUVAQUI"; 
		if substr(FI,1,2) in ("09" "11" "12" "30" "31" "32" "34" "46" "48" "65" "66" "81" "82") then region="OCCITANIE"; 
		if substr(FI,1,2) in ("44" "49" "53" "72" "85") then region="PDL"; 
		if substr(FI,1,2) in ("04" "05"	"06" "13" "83" "84") then region="PACA"; 
		if substr(FI,1,4) in ("9701") then region="GUADELOUPE"; 
		if substr(FI,1,4) in ("9702") then region="MARTINIQUE"; 
		if substr(FI,1,4) in ("9703") then region="GUYANE"; 
		if substr(FI,1,4) in ("9704") then region="REUNION"; 
		if substr(FI,1,2) in ("98") then region="MAYOTTE"; 	

		mavariable= &calcul. ; 
	
	run; 
	proc sql; 
		create table Q24_TMP2_&an1. as
		select distinct FI, FI_EJ, region, disci, sum(mavariable) as mavariable
		from Q24_TMP1_&an1.
		where region="&region."
		group by FI, FI_EJ, disci
	;quit; 
	proc transpose data=q24_tmp2_&an1. out=q24_&an1. (drop=_name_) prefix=dis_; 
		id disci ; 
		by fi fi_ej;
		var mavariable; 
	run; 
	data q24_&an1. ;
		retain fi fi_ej dis_2100 dis_2200 dis_2300 dis_2400 dis_2500 dis_2000 dis_1000 dis_9999; 
		set q24_&an1.; 
		label dis_2100 = "MCO (2100)"
		dis_2200 = "PSY (2200)" 
		dis_2300 = "HAD (2300)" 
		dis_2400 = "SSR (2400)" 
		dis_2500 = "USLD (2500)" 
		dis_2000= "Total section hôpital (2000)" 
		dis_1000= "Administration, services hôteliers et techniques (1000)" 
		dis_9999= "Total entité interrogée (9999)" ;
	run; 
	PROC EXPORT DATA= q24_&an1. OUTFILE = "~/requete_sae_q24_&region._&an2._&version."
		DBMS=xlsx
		REPLACE
		LABEL;
		SHEET="Q24_&selection";
	RUN;
%mend; 

/********************************************************************************************************
Objectif: Cette procédure permet de produire en sortie un fichier avec le calcul des ETP souhaités, 
issus de la SAE, détaillés par entité géographique et par champ d'activité (MCO, SSR , PSY).

Source utilisée: La table SAS Q24 de la SAE 

Fichier de sortie: 
		- format EXCEL 
		- dans perso-GRID(W:)

Procéduire à suivre: Il s'agit d'une macro programme SAS avec les paramètres à changer : 
		- Paramètre 1: La région 
		- Paramètre 2: L'année de la SAE
		- Paramètre 3: La version du fichier de sortie
		- Paramètre 4: Le calcul des ETP ou la variable souhaitée
		- Paramètre 5: Le nom de la feuille du fichier EXCEL  


**Exemple 1:  
%q24 (AURA,2020,V1,ETPPNM, Calcul ETPPNM total); 
		- Paramètre 1: AURA 
		- Paramètre 2: 2020 
		- Paramètre 3: V1
		- Paramètre 4: ETPPNM
		- Paramètre 5: Calcul ETPPNM total 
		
==> Cette requete permet de récupérer en sortie les ETP Non Médicaux totaux,
issus de la SAE 2020, par champ d'activité, et pour chaque entité géographique de la région AURA


**Exemple 2:
%q24 (BFC,2020,V1,sum(of AIDES ASHAU REEDU ADMIN EDUCS TECHN), Somme de certains ETP); 
		- Paramètre 1: BFC (Bourgogne-Franche-Comté)
		- Paramètre 2: 2020 
		- Paramètre 3: V1
		- Paramètre 4: sum(of AIDES ASHAU REEDU ADMIN EDUCS TECHN) (la somme des ETP souhaités)
		- Paramètre 5: Somme de certains ETP 
		
==> Cette requete permet de récupérer en sortie la somme du nombre d'ETP des aides-soignants(AIDES), des ASHQ et autres personnels de services(ASHAU),
des personnels de rééducation (REEDU), des autres personnels administratifs (ADMIN), des personnels éducatifs et sociaux (EDUCS) et 
des personnels techniques et ouvriers (TECHN) ; issus de la SAE 2020; par champ d'activité, et pour chaque entité géographique de la région Bourgogne-Franche-Comté. 



Pour faciliter la requete, nous avons prérempli les 3 premiers paramètres: la région, l'année et la version du fichier de sortie.
Les ARS pourront par la suite compléter les 2 derniers paramètres : le calcul des ETP souhaité et le nom de la feuille EXCEL. 
Attention: Les paramètres sont séparés par les virgules. 

******************************************************************************************************/

/*Requete à compléter et à exécuter : 5 paramètres */ 

%q24 (AURA,2020,V1,,); 
%q24 (BFC,2020,V1,,); 
%q24 (BRETAGNE,2020,V1,,); 
%q24 (CVL,2020,V1,,); 
%q24 (CORSE,2020,V1,,); 
%q24 (GRANDEST,2020,V1,,); 
%q24 (HAUTDEFRANCE,2020,V1,,); 
%q24 (ILEDEFRANCE,2020,V1,,); 
%q24 (NORMANDIE,2020,V1,,); 
%q24 (NOUVAQUI,2020,V1,,); 
%q24 (OCCITANIE,2020,V1,,); 
%q24 (PDL,2020,V1,,); 
%q24 (PACA,2020,V1,,); 
%q24 (GUADELOUPE,2020,V1,,); 
%q24 (MARTINIQUE,2020,V1,,); 
%q24 (GUYANE,2020,V1,,); 
%q24 (REUNION,2020,V1,,); 
%q24 (MAYOTTE,2020,V1,,);